GHS Port Reference Center
Information for maritime designers, engineers and builders
Maintained by Creative Systems, Inc., Creators of GHS
Click here for information about GHS and other fine marine software.
Go to Main page

A crane barge energy calculation simulating the sudden loss of a hook load ignoring damping, following 46 CFR 173.025.
    proj crane
    
    `A crane barge energy calculation simulating the sudden loss of a hook load
    `ignoring damping -- following 46 CFR 173.025.
    
    `Create a simple rectangular barge hull:
    units lt
    
    enter pm
    create hull
    ends 0 100
    top 6
    bot 0
    out 30
    /
    write
    quit pm
    
    report
    
    `Lightship weight & CG:
    draft 4
    vcg 12
    solve weight, lcg
    
    `Add counterbalance and hook loads:
    boom "counter" 100 50 0 15 20 -90 0
    boom "load" 40 50 0 11 80 90 10
    
    `Macro to show initial status:
    macro stat1
    solve
    page 75%  `minimum percent of page free to continue printing on page.
    \\\===== Before hook load is dropped =====\
    status
    /
    .stat1
    
    `Delete hook load:
    delete "load"
    
    `Macro to do calculations for the present case after dropping load:
    macro stat2
    solve trim `solve without changing heel
    \\\===== After hook load is dropped and before heel changes =====\
    status
    page
    \\\
    \ Note: The following righting arm curve represents heeling to port after
    \ the hook load is dropped.
    ra 0, -2, ... -30 /area:1-RA /stop:RA
    /
    .stat2
    
    
    `An equivalent method using heeling moments:
    
    delete all weights
    add "counter" 100 50 0 15 `on centerline
    add "load" 40 50 0 24.89 `on centerline
    hmmt 1151.38 /c1 `<-- load minus counterweight
    
    .stat1
    
    delete "load"
    hmmt -2000 `/c1 `<-- counterweight only
    
    .stat2
    
    `Finding max. VCG that meets energy requirement,
    `assuming maximum initial heel angle of 3 degrees:
    
    lim area from ABS -3 to RA0 or FLD > 7.0
    angles 0 2
    vcg = 0
    
    `Compute max VCG curve given a range of drafts:
    page
    maxvcg 3 3.25 ... 5
    
    `Find max VCG in present condition:
    st
    solve
    angles *
    ra/lim
    solve maxvcg /fixdir    `Keeps the heel direction from changing when solving for maximum VCG
    
    `Verify max VCG:
    page 75%   `minimum percent of page free to continue printing on page.
    \\--- At maximum VCG ---\
    ra /lim /stop:ra
    
    print preview
    
    report off
    end
    
    
    
    
Add a free link to your site
Copyright © , Creative Systems, Inc.
Privacy policy